In this chapter, you will learn about a keyword called deftemplate, which stands for
define template. This feature can aid you in writing rules whose patterns have a welldefined
structure.
Mr. Wonderful
Deftemplate is analogous to a struct definition in C. That is, the deftemplate defines a
group of related fields in a pattern similar to the way in which a C struct is a group of
related data. A deftemplate is a list of named fields called slots. Deftemplate allows
access by name rather than by specifying the order of fields. Deftemplate contributes to
good style in expert systems programs and is a valuable tool of software engineering.
A slot is a named single-slot or multislot. A single-slot or simply slot contains
exactly one field while a multislot contains zero or more fields. Any number of single or
multislot slots may be used in a deftemplate. To write a slot, give the field name
(attribute) followed by the field value. Note that a multislot slot with one value is strictly
not the same as a single-slot slot. As an analogy, think of a cupboard (the multislot) that
may contain dishes. A cupboard with one dish is not the same as a dish (single-slot.)
However, the value of a single-slot slot (or variable) may match a multislot slot (or
multislot variable) that has one field.
As an example of a deftemplate relation, consider the attributes of a duck who might
be considered a good matrimonial prospect.

Attributes Value
name "Dopey Wonderful"
assets rich
age 99
A deftemplate may be defined for the relation prospect as follows, where white space
and comments are used for readability and explanation.
(deftemplate prospect ;name of deftemplate relation
"vital information" ;optional comment in quotes
(slot name ;name of field
(type STRING) ;type of field
(default ?DERIVE)) ;default value of field name
(slot assets ;name of field
(type SYMBOL) ;type of field
(default rich)) ;default value of field assets
(slot age ;name of field
(type NUMBER) ;type. NUMBER can be INTEGER or FLOAT
(default 80))) ;default value of field age
In this example, the components of deftemplate are structured as:
• A deftemplate relation name
• Attributes called fields
• The field type, which can be any one of the allowed types:
SYMBOL, STRING, NUMBER, and others.
• The default for the field value
This particular deftemplate has three single-slot slots called name, assets, and age.
The deftemplate default values are inserted by CLIPS when a (reset) is done if no
explicit values are defined. For example, enter the deftemplate for prospect after a
(clear) command, and assert it as shown.
CLIPS> (assert (prospect))
<Fact-1>
CLIPS> (facts)
f-0 (initial-fact)
f-1 (prospect (name "") (assets rich) (age 80))
For a total of 2 facts.
CLIPS>

As you can see, CLIPS has inserted the default value of the null string, "", for the name
field since that is the default for a STRING. Likewise, the assets and age defaults were
also inserted by CLIPS. Different types have different default symbols such as the null
string, "", for STRING; the integer 0 for INTEGER; the float 0.0 for FLOAT and so on.
The ?DERIVE keyword selects the appropriate type of constraint for that slot, e.g., the
null string , "", for a slot of type STRING.
You can explicitly set the field values, as the following example shows.
CLIPS> (assert (prospect (age 99) (name "Dopey")))
<Fact-2>
CLIPS> (facts)
f-0 (initial-fact)
f-1 (prospect (name "") (assets rich) (age 80))
f-2 (prospect (name "Dopey") (assets rich) (age 99))
For a total of 3 facts.
CLIPS>
Note that the order that the fields are typed in does not matter since these are named
fields.
In the deftemplate, it's important to realize that NUMBER is not a primitive field type
like symbol, string, integer, and float. The NUMBER is really a compound type that can
be integer or float. It is used for cases in which the user doesn't care what type of
numbers are stored. An alternative to NUMBER would be specifying the types as
follows.
(slot age
(type INTEGER FLOAT)
(default 80)))
Bye-Bye
In general, a deftemplate with N slots has the following general structure:
(deftemplate <name>

(slot-1)
(slot-2)
...
(slot-N))
In a deftemplate, the attribute values may be specified more precisely than a simple
value such as 80 or rich. For example, in this deftemplate, a type of value is specified.
The field values can be specified by either explicitly listing them or giving a range of
values. The allowed-values can be any primitive type such as SYMBOL, STRING,
INTEGER, FLOAT and so on
