Rather than writing separate rules to handle each field, it's much easier to use the
multifield wildcard. This is a dollar sign followed by a question mark, "$?", and
represents zero or more fields. Notice how this contrasts with the single-field wildcard
which must match exactly one field.
The two rules for dates can now be written in a single rule as follows.
CLIPS> (clear)
CLIPS> (defrule dating-ducks
(bachelor Dopey $?)
=>
(printout t "Date Dopey" crlf))
CLIPS> (deffacts duck
(bachelor Dicky)
(bachelor Dopey)
(bachelor Dopey Mallard)
(bachelor Dinky Dopey)
(bachelor Dopey Dinky Mallard))
CLIPS> (reset)
CLIPS> (run)
Date Dopey
Date Dopey

Date Dopey
CLIPS>
Wildcards have another important use because they can be attached to a symbolic
field to create a variable such as ?x, $?x, ?name, or $?name. The variable can be a
single-field variable or a multifield variable depending on whether a "?" or "$?" is
used on the LHS. Note that on the RHS only a ?x is used, where the "x" can be any
variable name. You can think of the "$" as a function whose argument is a single-field
wildcard or a single-field variable and returns a multifield wildcard or a multifield
variable, respectively.
As an example of a multifield variable, the following version of the rule also prints out
the name field(s) of the matching fact because a variable is equated to the name field(s)
that match:
CLIPS> (defrule dating-ducks
(bachelor Dopey $?name)
=>
(printout t "Date Dopey " ?name crlf))
CLIPS> (reset)
CLIPS> (run)
Date Dopey (Dinky Mallard)
Date Dopey (Mallard)
Date Dopey ()
CLIPS>
As you can see, on the LHS, the multifield pattern is $?name but is ?name when used
as a variable on the RHS. When you enter and run, you'll see the names of all eligible
Dopeys. The multifield wildcard takes care of any number of fields. Also, notice that
multifield values are returned enclosed in parentheses.
Suppose you wanted a match of all ducks who had a Dopey somewhere in their
name, not necessarily as their first name. The following version of the rule would match
all facts with a Dopey in them and then print out the names:
CLIPS> (defrule dating-ducks
(bachelor $?first Dopey $?last)
=>
(printout t "Date " ?first " Dopey " ?last crlf))
CLIPS> (reset)
CLIPS> (run)

Date () Dopey (Dinky Mallard)
Date (Dinky) Dopey ()
Date () Dopey (Mallard)
Date () Dopey ()
CLIPS>
The pattern matches any names that have a Dopey anywhere in them.
Single- and multifield wildcards can be combined. For example, the pattern
(bachelor ? $? Dopey ?)
means that the first and last names can be anything and that the name just prior to the
last must be Dopey. This pattern also requires that the matching fact will have at least
four fields, since the "$?" matches zero or more fields and all the others must match
exactly four.
Although multifield variables can be essential for pattern matching in many cases,
their overuse can cause much inefficiency because of increased memory requirements
and slower execution.
• As a general rule of style, you should use $? only when you don't know the length of
fields. Do not use $? simply as a typing convenience
The Ideal Bachelor
Variables used in patterns have an important and useful property, which can be stated
as follows.
• The first time a variable is bound it retains that value only within the rule, both on the
LHS and also on the RHS, unless changed on the RHS.
For example, in the rule below
(defrule bound
(number-1 ?num)
(number-2 ?num)
=>)

If there are some facts
f-1 (number-1 0)
f-2 (number-2 0)
f-3 (number-1 1)
f-4 (number-2 1)
then the rule can only be activated by the pair f-1, f-2, and the other pair f-3, f-4. That is,
fact f-1 cannot match with f-4 because when ?num is bound to 0 in the first pattern, the
value of ?num in the second pattern also must be 0. Likewise, when ?num is bound to 1
in the first pattern, the value of ?num in the second pattern must be 1. Notice that the
rule will be activated twice by these four facts: one activation for the pair f-1, f-2, and the
other activation for the pair f-3, f-4.
As a more practical example, enter the following rule. Notice that the same variable,
?name, is used in both patterns. Before doing a (reset) and (run), also enter a (watch
all) command so that you can see what happens during execution.
CLIPS> (clear)
CLIPS> (defrule ideal-duck-bachelor
(bill big ?name)
(feet wide ?name)
=>
(printout t "The ideal duck is " ?name crlf))
CLIPS> (deffacts duck-assets
(bill big Dopey)
(bill big Dorky)
(bill little Dicky)
(feet wide Dopey)
(feet narrow Dorky)
(feet narrow Dicky))
CLIPS> (watch facts)
CLIPS> (watch activations)
CLIPS> (reset)
<== f-0 (initial-fact)
==> f-0 (initial-fact)
==> f-1 (bill big Dopey)
==> f-2 (bill big Dorky)
==> f-3 (bill little Dicky)
==> f-4 (feet wide Dopey)

==> Activation 0 ideal-duck-bachelor: f-1,f-4
==> f-5 (feet narrow Dorky)
==> f-6 (feet narrow Dicky)
CLIPS> (run)
The ideal duck is Dopey
CLIPS>
When the program is run, the first pattern matches Dopey and Dorky since they both
have big bills. The variable ?name is bound to each name. When CLIPS tries to match
the second pattern of the rule, only the variable ?name which is bound to Dopey also
satisfies the second pattern of (feet wide).
The Lucky Duck
Many situations occur in life where it's wise to do things in a systematic manner. That
way, if your expectations don't work out you can try again systematically (such as the
common algorithm for finding the Perfect Spouse by getting married over and over
again).
One way of being organized is to keep a list (Note: if you really want to impress
people, show them a list of your lists.) In our case, we'll keep a list of duck bachelors,
with the most likely prospect for matrimony at the front. Once an ideal duck bachelor
has been identified, we'll shoot him up to the front of the list as the lucky duck.
The following program shows how this can be done by adding a couple of rules to the
ideal-duck-bachelor rule.
(defrule ideal-duck-bachelor
(bill big ?name)
(feet wide ?name)
=>
(printout t "The ideal duck is " ?name crlf)
(assert (move-to-front ?name)))
(defrule move-to-front
?move-to-front <- (move-to-front ?who)
?old-list <- (list $?front ?who $?rear)
=>

(retract ?move-to-front ?old-list)
(assert (list ?who ?front ?rear))
(assert (change-list yes)))
(defrule print-list
?change-list <- (change-list yes)
(list $?list)
=>
(retract ?change-list)
(printout t "List is : " ?list crlf))
(deffacts duck-bachelor-list
(list Dorky Dinky Dicky))
(deffacts duck-assets
(bill big Dicky)
(bill big Dorky)
(bill little Dinky)
(feet wide Dicky)
(feet narrow Dorky)
(feet narrow Dinky))
The original list is given in the duck-bachelor-list deffacts. When the program is run, it
will provide a new list of likely candidates.
CLIPS> (unwatch all)
CLIPS> (reset)
CLIPS> (run)
The ideal duck is Dicky
List is : (Dicky Dorky Dinky)
CLIPS>
Notice the assertion (change-list yes) in the move-to-front rule. Without this assertion,
the print-list rule would always fire on the original list. This assertion is an example of a
control fact made to control the firing of another rule. Control facts are very important in
controlling the activation of certain rules, and you should study this example carefully to
understand why it's used. Another method of control is modules, as discussed in the
CLIPS Reference Manual.

The move-to-front rule removes the old list and asserts the new list. If the old list was
not retracted, two activations would be on the agenda for the print-list rule but only one
would fire. Only one will fire because the print-list rule removes the control fact required
for the other activation of the same rule. You would not know in advance which one
would fire, so the old list might be printed instead of the new list..

