Making a List
As with other programming languages, CLIPS recognizes certain keywords. For
example, if you want to put data in the fact-list, you can use the assert command.
As an example of assert, enter the following right after the CLIPS prompt as shown:
CLIPS> (assert (duck))
Here the assert command takes (duck) as its argument. Be sure to always press the
carriage return key to send the line to CLIPS.
You will see the response
<Fact-1>
which indicates CLIPS has stored the duck fact in the fact-list and given it the identifier
1. The angle-brackets are used as a delimiter in CLIPS to surround the name of an
item. CLIPS will automatically name facts using a sequentially increasing number and
list the highest fact-index when one or more facts is asserted.
Notice that the (assert) command and its (duck) argument are surrounded by
parentheses. Like many other expert system languages, CLIPS has a LISP-like syntax
which uses parentheses as delimiters. Although CLIPS is not written in LISP, the style
of LISP has influenced the development of CLIPS.
And Checking It Twice
Suppose you want to see what's in the fact-list. If your version of CLIPS supports a GUI,
you may just select the appropriate command from the menu. Alternatively, you can
enter commands from the keyboard. In the following, we'll describe the keyboard
commands since the window selections are self-explanatory.
The keyboard command to see facts is with the facts command. Enter (facts) in
response to the CLIPS prompt and CLIPS will respond with a list of facts in the fact-list.
Be sure to put parentheses around the command or CLIPS will not accept it. The result
of the (facts) command in this example should be
CLIPS> (facts)
f-0 (initial-fact)
f-1 (duck)
For a total of 2 facts.
CLIPS>
The terms f-0 and f-1 are the fact identifier assigned to each fact by CLIPS. Every
fact inserted into the fact-list is assigned a unique fact identifier starting with the letter "f"
and followed by an integer called the fact-index. On starting up CLIPS, and after certain
commands such as clear and reset (to be discussed in more detail later), the factindex
will be set to zero, and then incremented by one as each new fact is asserted.
The (reset) and (clear) commands will also insert a fact (initial-fact) as f-0. In prior
versions of CLIPS this fact was used implicitly by CLIPS to initially activate some types
of rules and could also be used explicitly by user programs to activate rules as well, but
is now only provided for backwards compatibility.
What happens if you try to put a second duck into the fact-list? Let's try it and see.
Assert a new (duck), then issue a (facts) command as follows
CLIPS> (assert (duck))
FALSE
CLIPS> (facts)
f-0 (initial-fact)
f-1 (duck)
For a total of 2 facts.
CLIPS>
The FALSE message is returned by CLIPS to indicate that it was not possible to
perform this command. You'll see just the original "f-1 (duck)". This shows that CLIPS
will not accept a duplicate entry of a fact. However, there is an override command,
set-fact-duplication, which will allow duplicate fact entry.
Of course you can put in other, different facts. For example, assert a (quack) fact and
then issue a (facts) command. You'll see
CLIPS> (assert (quack))
<Fact-2>
CLIPS> (facts)
f-0 (initial-fact)
f-1 (duck)
f-2 (quack)
For a total of 3 facts.

Notice that the (quack) fact is now in the fact-list.
Facts may be removed or retracted. When a fact is retracted, the other facts do not
have their indices changed, and so there may be "missing" fact-indices. As an analogy,
when a football player leaves a team and is not replaced, the jersey numbers of the
other players are not all adjusted because of the missing number (unless they really
hate the guy's guts and want to forget he ever played for them.)
Clearing Up the Facts
The clear command removes all facts from memory, as shown by the following.
CLIPS> (facts)
f-0 (initial-fact)
f-1 (duck)
f-2 (quack)
For a total of 3 facts.
CLIPS> (clear)
CLIPS>
and all facts in the fact-list will be removed.
The (clear) command essentially restores CLIPS to its original startup state. It clears
the memory of CLIPS, resets the fact-identifier to zero, and asserts the (initial-fact). To
see this, assert (animal-is duck), then check the fact-list. Notice that (animal-is duck)
has a fact-identifier of f-1 because the (clear) command reset the fact identifiers. The
(clear) command actually does more than just remove facts. Besides removing all the
facts, (clear) also removes all the rules, as you'll see in the next chapter.
The following example shows how three facts are asserted, and the (facts) command
is used. The (clear) command is used to get rid of all facts in memory and reset the factindices
to start with f-0.
CLIPS> (clear)
CLIPS> (assert (a) (b) (c))
<Fact-3>
CLIPS> (facts)
f-0 (initial-fact)
f-1 (a)
f-2 (b)
f-3 (c)
For a total of 4 facts.
CLIPS> (facts 0)
f-0 (initial-fact)
f-1 (a)
f-2 (b)
f-3 (c)
For a total of 4 facts.
CLIPS> (facts 1)
f-1 (a)
f-2 (b)
f-3 (c)
For a total of 3 facts.
CLIPS> (facts 2)
f-2 (b)
f-3 (c)
For a total of 2 facts.
CLIPS> (facts 1 2)
f-1 (a)
f-2 (b)
For a total of 2 facts.
CLIPS> (facts 1 3 2)
f-1 (a)
f-2 (b)
For a total of 2 facts.
CLIPS>
Notice only one (assert) is used to assert the three facts, (a), (b), and (c). The highest
fact-index is 3 and this is returned by CLIPS in the informational message <Fact-3>.
The much longer alternative would be to assert one fact per command (This may be
done by people who like to show off their typing speed.)
Sensitive Fields and Slurping
A fact such as (duck) or (quack) is said to consist of a single field. A field is a
placeholder (named or unnamed) that may have a value associated with it. As a simple
analogy, you can think of a field as a picture frame. The frame can hold a picture,
perhaps a picture of your pet duck (For those of you who are curious what a picture of a"quack" looks like, it could be (1) a photo of an oscilloscope trace of a duck saying
"quack", where the signal input comes from a microphone, or (2) for those of you who
are more scientifically inclined, a Fast Fourier Transform of the "quack" signal, or (3) a
TV-huckster selling a miracle cure for wrinkles, losing weight, etc.). Named placeholders
are only used with deftemplates, described in more detail in chapter 5.
The (duck) fact has a single, unnamed placeholder for the value duck. This is an
example of a single-field fact. A field is a placeholer for a value. As an analogy to
fields, think of dishes (fields) for holding food (values).
The order of unnamed fields is significant. For example, if a fact was defined
(Brian duck)
and interpreted by a rule as the hunter Brian shot a duck, then the fact
(duck Brian)
would mean that the hunter duck shot a Brian. In contrast, the order of named fields is
not significant, as you'll see later with deftemplate.
Actually, it is good software engineering to start the fact with a relation that describes
the fields. A better fact would be
(hunter-game duck Brian)
to imply that the first field is the hunter and the second field is the game.
A few definitions are now necessary. A list is a group of items with no implied order.
Saying that a list is ordered means that the position in the list is significant. A
multifield is a sequence of fields, each of which may have a value. The examples of
(duck Brian) and (Brian duck) are multifield facts. If a field has no value, the special
symbol nil, which means "nothing" may be used for an empty field as a placeholder. For
example,
(duck nil)
would mean that the killer duck bagged no trophies today.
Note that the nil is necessary to indicate a placeholder, even if it has no value. For
example, think of a field as analogous to a mailbox. There's a big difference between an
empty mailbox, and no mailbox at all. Without the nil, the fact becomes a single-field fact
(duck). If a rule depends on two fields, it will not work with only one field, as you'll see
later.
There are a number of different types of fields available: float, integer, symbol,
string, external-address, fact-address, instance-name and instance-address The
type of each field is determined by the type of value stored in the field. In an unnamed
field, the type is determined implicitly by what type you put in the field. In deftemplates,
you can explicitlty declare the type of value that a field can contain. The use of explicit
types enforces the concepts of software engineering, which is a discipline of
programming to produce quality software.
A symbol is one type of field that starts with a printable ASCII character and is
followed optionally by zero or more printable characters. Fields are commonly delimited
or bounded, by one or more spaces or parentheses. For example,
(duck-shot Brian Gary Rey)
has four fields to indicate all the hunters shot by the killer duck. In this fact, the fields are
delimited by spaces, and the opening and closing parentheses.
Facts are not allowed to be embedded within other facts. For example, the following
is an illegal ordered fact.
(duck (shot Brian Gary Rey))
However, this could be a legal deftemplate fact if "shot" is defined as the name of a
field, while "Brian Gary Rey" are the values associated with the named field.
CLIPS is case-sensitive. Also, certain characters have special meaning to CLIPS.
" ( ) & | < ~ ; ? $
The "&", "|", and "~" may not be used as stand-alone symbols or as any part of a
symbol.
Some characters act as delimiters by ending a symbol. The following characters act
as delimiters for symbols.
• any non-printable ASCII character, including spaces, carriage returns, tabs, and
Linefeeds • double quotes, "
• opening and closing parentheses, ()
• ampersand, &
• vertical bar, |
• less than, <. Note that this may be the first character of a symbol
• tilde, ~
• semicolon, ; indicates start of a comment, a carriage return ends it
• ? and $? may not begin a symbol but may be inside it
The semicolon acts as the start of a comment in CLIPS. If you try to assert a
semicolon, CLIPS will think you're entering a comment and wait for you to finish. If you
accidentally enter a semicolon in top-level, just type in a closing parenthesis and
carriage return. CLIPS will respond with an error message and the CLIPS prompt will
reappear (This is one of the few approved occasions in life in which it's necessary to do
something wrong to get something right.)
As you read through this manual, you will learn the special meanings of the
characters above. With the exception of the "&", "|", and "~", you may use the others as
described. However, it may be confusing to someone reading your program and trying
to understand what the program is doing. In general, it's best to avoid using these
characters in symbols unless you have some good reason for using them.
The following are examples of symbols.
duck
duck1
duck_soup
duck-soup
duck1-1_soup-soup
d!?#%^
The second type of field is the string. A string must begin and end with double
quotes. The double quotes are part of the field. Zero or more characters of any kind can
appear between the double quotes. Some examples of strings follow.
"duck"
"duck1"
"duck/soup"
"duck soup"
"duck soup is good!!!"
The third and fourth types of field are numeric fields. A field which represents a
number which can be either an integer or floating-point type field. A floating-point type
is commonly referred to simply as a float.
All numbers in CLIPS are treated as “long long” integers or double-precision floats.
Numbers without a decimal point are treated as integers unless they are outside integer
range. The range is machine dependent on the number of bits, N, used to represent the
integer as follows.
- 2N-1 ... 2N-1-1
For 64-bit “long long” integers, this corresponds to a range of numbers
- 9,223,372,036,854,775,808 ... 9,223,372,036,854,775,807
As some examples of numbers, assert the following data where the last number is in
exponential notation, and uses the "e" or "E" for the power-of-ten.
CLIPS> (clear)
CLIPS> (facts)
f-0 (initial-fact)
For a total of 1 fact.
CLIPS> (assert (number 1))
<Fact-1>
CLIPS> (assert (x 1.5))
<Fact-2>
CLIPS> (assert (y -1))
<Fact-3>
CLIPS> (assert (z 65))
<Fact-4>
CLIPS> (assert (distance 3.5e5))
<Fact-5>
CLIPS> (assert (coordinates 1 2 3))
<Fact-6>
CLIPS> (assert (coordinates 1 3 2))
<Fact-7>
CLIPS> (facts)
f-0 (initial-fact)
f-1 (number 1)
f-2 (x 1.5)
f-3 (y -1)
f-4 (z 65)
f-5 (distance 350000.0)
f-6 (coordinates 1 2 3)
f-7 (coordinates 1 3 2)
For a total of 8 facts.
CLIPS>
As you can see, CLIPS prints the number entered in exponential notation as 350000.0
because it converts from power-of-ten format to floating-point if the number is small
enough.
Notice that each number must start with a symbol such as "number", "x", "y", etc.
Before CLIPS version 6.0, it was possible to enter only a number as a fact. However,
now a symbol is required as the first field. Also, certain reserved words used by CLIPS
cannot be used as the first field, but may be used for other fields. For example, the
reserved word not is used to indicate a negated pattern and may not be used as the first
field of a fact.
A fact consists of one or more fields enclosed in matching left and right parentheses.
For simplicity we'll only discusss facts in the first seven chapters, but most of the
discussion of pattern matching applies to objects as well. Exceptions are certain
functions such as assert and retract which only apply to facts, not objects. The
corresponding ways to handle objects are discussed in chapters 8–12.
A fact may be ordered or unordered. All the examples you've seen so far are
ordered facts because the order of fields makes a difference. For example, notice that
CLIPS considers these as separate facts although the same values "1", "2", and "3" are
used in each.
f-6 (coordinates 1 2 3)
f-7 (coordinates 1 3 2)
Ordered facts must use field position to define data. As an example, the ordered fact
(duck Brian) has two fields and so does (Brian duck). However, these are considered as
two separate facts by CLIPS because the order of field values is different. In contrast,
the fact (duck-Brian) has only one field because of the "-" concatenating the two values.
Deftemplate facts, described in more detail later, are unordered because they use
named fields to define data. This is analogous to the use of structs in C and other languages.
Multiple fields normally are separated by white space consisting of one or more
spaces, tabs, carriage returns, or linefeeds. For example, enter the following examples
as shown and you'll see that each stored fact is the same.
CLIPS> (clear)
CLIPS> (assert (The duck says "Quack"))
<Fact-1>
CLIPS> (facts)
f-0 (initial-fact)
f-1 (The duck says "Quack")
For a total of 2 facts.
CLIPS> (clear)
CLIPS> (assert (The duck says "Quack" ))
<Fact-1>
CLIPS> (facts)
f-0 (initial-fact)
f-1 (The duck says "Quack")
For a total of 2 facts.
CLIPS>
Carriage returns may also be used to improve readability. In the following example, a
carriage return is typed after every field and the asserted fact is the same as before
when the fact was entered on one line.
CLIPS> (clear)
CLIPS> (assert (The
duck
says
"Quack"))
<Fact-1>
CLIPS> (facts)
f-0 (initial-fact)
f-1 (The duck says "Quack")
For a total of 2 facts.
CLIPS>
However, be careful if you insert a carriage return inside of a string, as the following
example shows.

CLIPS>
As you can see, CLIPS replaced the carriage returns and tabs with single spaces.
While the use of white space in separating the facts is convenient for a person reading a
program, they are converted to single spaces by CLIPS.
